今天，正運動技術來分享一下，運動控制器多軸同步與電子凸輪指令。這一章節(jié)，我們主要分享運動疊加、電子齒輪、電子齒輪2和連接速度等多軸同步指令，以及凸輪表運動、跟隨凸輪表運動、自動凸輪和自動凸輪2等凸輪運動指令。

　　視頻教程：《 視頻教程：正運動技術運動控制器多軸同步與電子凸輪指令簡介》

　　 材料準備

　　1.電腦1臺，安裝ZDevelop V3.10及以上版本軟件;

　　2.控制器1個;

　　3.24V直流電源1個;

　　4.驅(qū)動器、電機若干;

　　5.控制器接線端子若干;

　　6.網(wǎng)線若干;

　　7.連接線若干;

　　8.輸入輸出設備、擴展模塊、人機界面等根據(jù)實際需求選擇。

　　接線參考

　　本節(jié)指令一覽

　　 1    ADDAX --運動疊加

　　語法：

　　疊加：ADDAX(疊加軸號) AXIS(被疊加軸號)

　　取消疊加：ADDAX(-1) AXIS(被疊加軸號)

　　ADDAX指令將2個或多個運動疊加形成較復雜的運動軌跡。

　　ADDAX指令把疊加軸的目標位置(DPOS)的變化，附加到指令指向的軸的任意運動上。疊加軸可以是任一軸，不一定在系統(tǒng)里物理存在，支持虛擬軸疊加。

　　ADDAX指令發(fā)出后兩軸的鏈路保持連接，指定疊加軸上的進一步運動被附加到基準軸上。直到使用ADDAX(-1)取消軸的連接。

　　ADDAX指令疊加的是脈沖個數(shù)，而不是設置的UNITS單位。

　　轉(zhuǎn)換關系：疊加軸運動距離*疊加軸UNITS/被疊加軸UNITS=被疊加軸運動距離。

　　假設軸A的UNITS是100，軸B的UNITS是50，疊加軸運動100。

　　把軸A的運動疊加到軸B，疊加軸軸A顯示運動了100，軸B運動了100*100/50=200。

　　把軸B的運動疊加到軸A，疊加軸軸B顯示運動了100，軸A運動了100*50/100=50。

　　軸之間不能相互同時疊加，A疊加到B后，B不能再疊加到A。

　　支持串聯(lián)疊加，A運動疊加到B，B在疊加到C。

　　支持并聯(lián)疊加，A運動同時疊加到B、C。

　　疊加時速度從被疊加軸開始變化，加減速按照疊加軸加減速及兩軸UNITS比例確定。

　　ADDAX在軸MTYPE為CONNFRAME或CONNREFRAME的時候不起作用。

　　例子：

　　RAPIDSTOP(2)

　　WAIT IDLE

　　BASE(0,1)

　　DPOS=0,0

　　ATYPE=1,1

　　UNITS=100,100         '脈沖比例為1:1

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　ADDAX(0) AXIS(1)         '軸0的運動疊加到軸1

　　TRIGGER

　　MOVE(200) AXIS(0)

　　MOVE(-100) AXIS(1)

　　WAIT IDLE         '等待運行完

　　ADDAX(-1) AXIS(1)         '取消疊加

　　疊加前：

　　疊加后：

　　后續(xù)給軸0發(fā)運動指令，軸0軸1一起運動，仍保持疊加，直到ADDAX(-1) AXIS(1)取消疊加。

　 　2    CONNECT --電子齒輪

　　將當前軸的目標位置與驅(qū)動軸的測量位置通過電子齒輪連接。

　　語法：CONNECT(比率，被連接軸) AXIS(連接軸)

　　電子齒輪的連接比率：比率可正可負，可為小數(shù)，連接的是脈沖個數(shù)，要考慮不同軸UNITS的比例。

　　比率可以通過重復調(diào)用CONNECT指令動態(tài)變化，連接成功后保持連接狀態(tài)，取消連接時用CANCEL。

　　兩軸連接成功之后，連接軸跟隨被連接軸運動，兩軸的運動同時開啟同時停止，連接軸的運動速度自動計算，連接比率過大會導致連接軸的速度過大。

　　連接狀態(tài)下無法單獨給連接軸發(fā)送運動指令。

　　假設連接軸0的UNIST為10，被連接軸1的UNITS為100，使用CONNECT連接，比率ratio為1，CONNECT(1,1) AXIS(0) 。

　　當軸1運動S1=100時，軸0運動S0=S1*UNITS(1)*ratio/UNITS(0)=100*100*1/10，此時運動1000。

　　例一：

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　UNITS=10,100

　　DPOS=0,0

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　TRIGGER                                        '自動觸發(fā)示波器

　　MOVE(100) AXIS(1)                       '軸1運動100，此時軸0不動

　　WAIT IDLE(1)                                '上一段運動不連接

　　CONNECT(1,1) AXIS(0)                 '軸0連接到軸1，比例為1

　　MOVE(100) AXIS(1)                      '軸1運動100，軸0運動1000

　　軸0目標位置：DPOS(0)=DPOS(1)*UNITS(1)*ratio/UNITS(0)=100*100*1/10=1000

　　例二：修改連接比例

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　UNITS=10,100

　　DPOS=0,0

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　TRIGGER                                                '自動觸發(fā)示波器

　　MOVE(100) AXIS(1)                               '軸1運動100，此時軸0不動

　　WAIT IDLE(1)                                         '上一段運動不連接

　　CONNECT(0.5,1) AXIS(0)                       '軸0連接到軸1，比例為0.5

　　MOVE(100) AXIS(1)                               '軸1運動100，軸0運動1000

　　軸0目標位置：DPOS(0)=DPOS(1)*UNITS(1)*ratio/UNITS(0)=100*100*0.5/10=500

　　3    CONNPATH -- 電子齒輪2

　　將當前軸的目標位置驅(qū)動軸的插補矢量長度通過電子齒輪連接。

　　CONNPATH與CONNECT的區(qū)別：CONNECT連接的是單個軸的目標位置。CONNPATH是連接的是插補軸的矢量長度，此時需要連接在插補運動的主軸上，連接到插補從軸上無法跟隨插補運動。例如跟蹤XY軸插補的的矢量長度變化，而不是跟蹤單獨的X軸或者Y軸。

　　CONNPATH連接到單個軸的運動的效果與CONNECT相同。

　　語法：CONNPATH(比率，被連接軸) AXIS(連接軸)

　　電子齒輪的連接比率：比率可正可負，可為小數(shù)，連接的是脈沖個數(shù)，要考慮不同軸UNITS的比例。

　　比率可以通過重復調(diào)用CONNPATH指令動態(tài)變化，連接成功后保持連接狀態(tài)，取消連接時用CANCEL。

　　兩軸連接成功之后，連接軸跟隨被連接軸運動，兩軸的運動同時開啟同時停止，連接軸的運動速度自動計算，連接比率過大會導致連接軸的速度過大。

　　連接狀態(tài)下無法單獨給連接軸發(fā)送運動指令。

　　假設連接軸0的UNIST為10，被連接軸1的UNITS為100，使用CONNPATH連接，比率ratio為2，CONNPATH(0.5,1) AXIS(0) 。

　　當軸1運動S1=100時，軸0運動S0=S1*UNITS(1)*ratio/UNITS(0)=100*100*0.5/10，此時運動500。

　　例一：連接到插補主軸

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　WAIT     IDLE(2)

　　BASE(0,1,2)

　　DPOS=0,0,0

　　ATYPE=1,1,1

　　UNITS=100,100,100

　　SPEED=100,100,100

　　ACCEL=1000,1000,1000

　　DECEL=1000,1000,1000

　　TRIGGER                                    '自動觸發(fā)示波器

　　CONNPATH(1,0) AXIS(2)           '軸2連接到插補主軸軸0，比例為1

　　MOVE(100,100)                         '軸1軸0插補運動

　　連接在插補運動主軸軸0上，連接軸軸2的運動距離為插補運動合成距離。

　　例二：CONNPATH與CONNECT的效果對比，例一CONNPATH換成CONNECT。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　WAIT     IDLE(2)

　　BASE(0,1,2)

　　DPOS=0,0,0

　　ATYPE=1,1,1

　　UNITS=100,100,100

　　SPEED=100,100,100

　　ACCEL=1000,1000,1000

　　DECEL=1000,1000,1000

　　TRIGGER                                       '自動觸發(fā)示波器

　　CONNECT(1,0) AXIS(2)                 '軸2連接到插補主軸軸0，比例為1

　　MOVE(100,100)                            '軸1軸0插補運動

　　同樣的例程，CONNECT只能連接到單個軸運動。

　　例三：連接到插補從軸，例一改變連接軸。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　WAIT     IDLE(2)

　　BASE(0,1,2)

　　DPOS=0,0,0

　　ATYPE=1,1,1

　　UNITS=100,100,100

　　SPEED=100,100,100

　　ACCEL=1000,1000,1000

　　DECEL=1000,1000,1000

　　TRIGGER                                      '自動觸發(fā)示波器

　　CONNPATH(2,1) AXIS(2)             '軸2連接到軸1，比例為2

　　MOVE(100,100)                           '軸1軸0插補運動

　　MOVE(100) AXIS(1)                     '軸1運動100

　　連接到插補的從軸可以連接成功，但無法跟隨插補運動。

　　4    CLUTCH_RATE -- 連接速度

　　CONNECT連接的速度，默認值1000000，用于定義連結(jié)率從0到設置倍率的改變時間，ratio/秒。

　　CONNPATH同樣適用。

　　采用默認值時根據(jù)連接的倍率自動計算連接軸的速度與加速度，實際連接比例為設置的比例。

　　設置值如果不能遠大于CONNECT連接比例的話，實際連接比例會減小。

　　當設置為0時，根據(jù)跟隨軸的速度/加速度參數(shù)來跟蹤連接，比較適合于手輪運動(當速度不夠高時可能導致要持續(xù)運動一段時間才能結(jié)束)。

　　例一：CLUTCH_RATE=1

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　DPOS=0,0

　　UNITS=100,100

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　CLUTCH_RATE=1                             '設置連接速度，倍率/s

　　TRIGGER                                          '自動觸發(fā)示波器

　　CONNECT(2,1) AXIS(0)                     '連接倍率為2，需要2秒建立連接

　　MOVE(200) AXIS(1)                          '運動軸1，軸0跟隨

　　實際連接比例小于設置比例。

　　例二：CLUTCH_RATE=3

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　DPOS=0,0

　　UNITS=100,100

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　CLUTCH_RATE=3                     '設置連接速度，倍率/s

　　TRIGGER                                   '自動觸發(fā)示波器

　　CONNECT(2,1) AXIS(0)             '連接倍率為2，需要2秒建立連接

　　MOVE(200) AXIS(1)                  '運動軸1，軸0跟隨

　　實際連接比例小于設置比例，值越大越接近設置比例。

　　例三：CLUTCH_RATE=1000000

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　DPOS=0,0

　　UNITS=100,100

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　CLUTCH_RATE=1000000                 '設置連接速度，倍率/s

　　TRIGGER                                          '自動觸發(fā)示波器

　　CONNECT(2,1) AXIS(0)                    '連接倍率為2，需要2秒建立連接

　　MOVE(200) AXIS(1)                         '運動軸1，軸0跟隨

　　實際連接比例為設置比例。

　　例四：CLUTCH_RATE=0

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0,1)

　　ATYPE=1,1

　　DPOS=0,0

　　UNITS=100,100

　　SPEED=100,100

　　ACCEL=1000,1000

　　DECEL=1000,1000

　　CLUTCH_RATE=0                      '設置連接速度，倍率/s

　　TRIGGER                                    '自動觸發(fā)示波器

　　CONNECT(2,1) AXIS(0)              '連接倍率為2，需要2秒建立連接

　　MOVE(200) AXIS(1)                   '運動軸1，軸0跟隨

　　隨軸運動軸的的速度/加速度參數(shù)運動，實際連接比例為設置比例。

　　前三種情況兩個軸都是同步的，最后一種情況當比例不為1的時候不同步。

　 　5    CAM --凸輪表運動

　　根據(jù)存儲在TABLE中的數(shù)據(jù)來決定軸的運動，這些TABLE數(shù)據(jù)值對應運動軌跡的位置，是相對于運動起始點的絕對位置。

　　語法：CAM(start point, end point, table multiplier, distance)

　　start point：起始點TABLE編號，存儲第一個點的位置。

　　end point：結(jié)束點TABLE編號。

　　table multiplier：位置乘以這個比例，一般設為脈沖當量值，TABLE數(shù)據(jù)*table multiplier值=實際發(fā)出的脈沖數(shù)。

　　distance：參考運動的距離，總時間=distance/軸speed。

　　運動的總時間由設置速度和第四個參數(shù)決定，運動的實際速度根據(jù)TABLE軌跡與時間自動匹配，軌跡一定的情況下，時間越短，運動速度越大。

　　TBALE數(shù)據(jù)需要手動設置，第一個數(shù)據(jù)為引導點，建議設為0。

　　請確保指令傳遞的距離參數(shù)*UNITS是整數(shù)個脈沖，否則出現(xiàn)浮點數(shù)會導致運動有細微誤差。

　　例一：

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　BASE(0)         '選擇第0軸

　　ATYPE=1       '脈沖方式步進或伺服

　　DPOS = 0

　　UNITS = 100 '脈沖當量

　　SPEED = 200

　　ACCEL = 2000

　　DECEL = 2000

　　'計算TABLE的數(shù)據(jù)

　　DIM deg, rad, x, stepdeg

　　stepdeg = 2     '可以通過這個來修改段數(shù)，段數(shù)越多速度越平穩(wěn)

　　FOR deg=0 TO 360 STEP stepdeg

　　rad = deg * 2 * PI/360     '轉(zhuǎn)換為弧度

　　X = deg * 25 + 10000 * (1-COS(rad))     '計算每小段位移

　　TABLE(deg/stepdeg,X)     '存儲TABLE

　　TRACE deg/stepdeg,X

　　NEXT deg

　　TRIGGER     '觸發(fā)示波器采樣

　　WHILE 1     '循環(huán)運動

　　CAM(0, 360/stepdeg, 0.1, 300)     '虛擬跟蹤總長度300

　　WAIT UNTIL IDLE     '等待運動停止

　　WEND

　　END

　　TABLE存儲的凸輪表參數(shù)：

　　運動軌跡：

　　每個凸輪指令運動總時間=distance/speed=300/200=1.5s

　　例二：高速高精度運動上的應用

　　DIM num_p,scale,m,t     '變量定義

　　num_p=100

　　scale=500

　　FOR p=0 TO num_p     'table存儲凸輪表運動參數(shù)

　　TABLE(p,((-SIN(PI*2*p/num_p)/(PI*2))+p/num_p)*scale)

　　NEXT

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0)     '選擇軸0

　　DEFPOS(0)

　　UNITS=500

　　SPEED=1000

　　ACCEL=1000000

　　DECEL=1000000

　　TRIGGER

　　m=10         '代表距離的倍數(shù)

　　t=0.3         '運行時間

　　SPEED=1000

　　CAM(0,100,m,SPEED*t)

　　WAIT IDLE

　　m=10

　　t=0.3

　　SPEED=1000

　　CAM(0,100,-m,SPEED*t)

　　WAIT IDLE

　　m=10

　　t=0.2

　　SPEED=500

　　CAM(0,100,m,SPEED*t)

　　WAIT IDLE

　　m=10

　　t=0.2

　　SPEED=500

　　CAM(0,100,-m,SPEED*t)

　　WAIT IDLE

　　m=20

　　t=0.3

　　SPEED=1000

　　CAM(0,100,m,SPEED*t)

　　WAIT IDLE

　　m=20

　　t=0.5

　　SPEED=500

　　CAM(0,100,-m,SPEED*t)

　　WAIT IDLE

　　TABLE存儲的凸輪表參數(shù)：

　　從TABLE(0)=0開始，存儲數(shù)據(jù)大小模擬正弦函數(shù)曲線逐漸增加，到TABLE(100)=500結(jié)束。

　　六段凸輪表運動，運動總時間1800ms。實際發(fā)出脈沖數(shù)=m*table數(shù)據(jù)，針對一個段凸輪運動，DPOS=實際發(fā)出脈沖數(shù)/UNITS=10*500/500=10，第一段運動時間300ms。

　　 6    CAMBOX --凸輪表運動

　　根據(jù)存儲在TABLE中的數(shù)據(jù)來決定軸的運動，這些TABLE數(shù)據(jù)值對應運動軌跡的位置，是相對于運動起始點的絕對位置。

　　語法：CAMBOX(start_point, end_point, table_multiplier, link_distance , link_axis[, link_options][, link_pos][, link_offpos])

　　start point：起始點TABLE編號，存儲第一個點的位置。

　　end point：結(jié)束點TABLE編號。

　　table multiplier：位置乘以這個比例，一般設為脈沖當量值，TABLE數(shù)據(jù)*table multiplier值=實際發(fā)出的脈沖數(shù)。

　　link_distance：參考軸運動的距離，總時間=distance/軸speed。

　　link_axis：參考軸軸號。

　　link_options：與參考軸的連接方式，不同的二進制位代表不同的意義。

　　link_pos：當link_options參數(shù)設置為2時，該參數(shù)表示連接開始啟動的絕對位置。

　　link offpos：當link_options參數(shù)bit4置為1時，該參數(shù)表示主軸已經(jīng)運行完的相對位置。

　　連接到參考軸后，參考軸停止，跟隨軸不管有沒有運動完也停止。

　　運動的總時間由設置速度和第四個參數(shù)決定，運動的實際速度根據(jù)TABLE軌跡與時間自動匹配，軌跡一定的情況下，時間越短，運動速度越大。

　　兩個或多個CAMBOX指令可以同時使用同一段TABLE數(shù)據(jù)區(qū)進行操作。

　　TBALE數(shù)據(jù)需要手動設置，第一個數(shù)據(jù)為引導點，建議設為0。

　　請確保指令傳遞的距離參數(shù)*UNITS是整數(shù)個脈沖，否則出現(xiàn)浮點數(shù)會導致運動有細微誤差。

　　例一：連接到參考軸之后，若參考軸停止運動，則凸輪軸跟隨停止。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)     '選擇軸號

　　ATYPE=1,1    '脈沖方式步進或伺服

　　DPOS = 0,0

　　UNITS = 100,100     '脈沖當量

　　SPEED = 200,200

　　ACCEL = 2000,2000

　　DECEL = 2000,2000

　　DIM rad, x

　　FOR i=0 TO 100 STEP 1

    　　rad = i* 2 * PI/100     '轉(zhuǎn)換為弧度

    　　x = 1000 * (1-COS(rad))

    　　TABLE(i,x)     '存儲TABLE

　　NEXT i

　　TRIGGER             '自動觸發(fā)示波器

　　CAMBOX(0,100, 100, 2000, 1,2,100) AXIS(0)         '參考軸軸1運動到100位置時，跟隨軸軸0啟動

　　VMOVE(1) AXIS(1)

　　例二：連接到參考軸之后，若參考軸停止運動，則凸輪軸跟隨停止。

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0,1)         '選擇軸號

　　ATYPE=1,1         '脈沖方式步進或伺服

　　DPOS = 0,0

　　UNITS = 100,100            '脈沖當量

　　SPEED = 200,200

　　ACCEL = 2000,2000

　　DECEL = 2000,2000

　　DIM rad, x

　　FOR i=0 TO 100 STEP 1

　　rad = i* 2 * PI/100             '轉(zhuǎn)換為弧度

　　x = 1000 * (1-COS(rad))

　　TABLE(i,x)         '存儲TABLE

　　NEXT i

　　TRIGGER         '自動觸發(fā)示波器

　　CAMBOX(0,100, 100, 2000, 1,2,100) AXIS(0) '參考軸軸1運動到100位置時，跟隨軸軸0啟動

　　MOVE(1500) AXIS(1)

　　參考軸1運動1500便停止，跟隨軸軸0也停下，無法將調(diào)用的TABLE表的數(shù)據(jù)運動完。

　 　7    MOVELINK --自動凸輪

　　自定義凸輪運動，不用計算凸輪表，該運動帶有可設置的加減速階段。

　　將跟隨軸連接到參考軸上，控制跟隨軸跟隨參考軸運動。

　　連接軸的距離分成3個階段應用于參考軸的運動，分別是加速部分、勻速部分和減速部分。

　　語法：MOVELINK (distance,ink dist,link acc,link dec,link axis[,link options] [,ink pos][,link offpos])

　　distance：從連接開始到結(jié)束，跟隨軸移動的距離，此參數(shù)可正可負，為正數(shù)正方向跟隨，為負數(shù)負方向跟隨，采用units單位。

　　link dist：參考軸在連接的整個過程中移動的絕對距離，采用units單位。

　　link acc：在跟隨軸加速階段，參考軸移動的絕對距離，采用units單位。

　　link dec：在跟隨軸減速階段，參考軸移動的絕對距離，采用units單位。

　　link axis：參考軸的軸號。

　　后三個參數(shù)選擇連接模式，可以不設置。

　　link options：連接模式選項，不同的二進制位代表不同的意義。

　　link pos：當link options參數(shù)bit1置為1時，該參數(shù)表示基本軸在該絕對位置值時，連接開始。

　　link offpos：當link_options參數(shù)bit4置為1時，該參數(shù)表示主軸已經(jīng)運行完的相對位置。20170428以上固件支持。

　　在加速和減速階段為了與速度匹配，link distance(基本軸運動距離)必須是distance(跟隨軸運動距離)的兩倍。

　　請確保指令傳遞的距離參數(shù)*UNITS是整數(shù)個脈沖，否則出現(xiàn)浮點數(shù)會導致運動有細微誤差。

　　例一：不設置加減速

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)    '軸0為跟隨軸，軸1為參考軸

　　UNITS=100,100

　　ATYPE=1,1

　　DPOS=0,0

　　SPEED=100,100

　　ACCEL=2000,2000

　　DECEL=2000,2000

　　TRIGGER                 '自動觸發(fā)示波器

　　MOVELINK(100,100,0,0,1) AXIS(0)         '不設置加減速階段

　　MOVE(150) AXIS(1)         '軸1運動150，軸0跟隨軸1運動完100

　　不設置加減速階段時，效果與CONNECT相同，區(qū)別在不需要考慮UNITS的不同，且不會有累積誤差。運動比例為前兩個參數(shù)的比值，此時運動比例1:1。

　　例二：飛剪應用，不設置連接模式link options。

　　假設要切的型材長度為4m，工作臺運行距離1m。

　　軸1為參考軸(型材傳送)，軸0為跟隨軸(追剪工作臺)。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　UNITS=100000,100000

　　ATYPE=1,1

　　DPOS=0,0

　　SPEED=1,1     '型材運行速度1m/s,60m/min

　　ACCEL=2,2

　　DECEL=2,2

　　MERGE=on,on

　　MOVELINK(0,1,0,0,1)     AXIS(0)         '型材運動1m前，工作臺靜止

　　MOVELINK(0.4,0.8,0.8,0,1)     AXIS(0)     '工作臺加速階段，工作臺運動0.4，型材運動0.8

　　MOVELINK(0.2,0.2,0,0,1)     AXIS(0)     '速度同步跟隨0.2

　　MOVE_OP2(0,on,1000)     '刀具下剪，1s后回升(時間要計算好)

　　MOVELINK(0.4,0.8,0,0.8,1)     AXIS(0)     '工作臺減速階段，工作臺運動0.4，型材運動0.8

　　MOVELINK(-1,1.2,0.5,0.5,1)     AXIS(0)     '工作臺回到起始點，工作臺加速運動0.5，再減速運動0.5，總距離1;此段型材運動1.2

　　TRIGGER '自動觸發(fā)示波器

　　VMOVE(1) AXIS(1) '型材持續(xù)運動

　　例三：設置link options bit3=1時，從軸追剪軸采用S曲線加減速。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　UNITS=100000,100000

　　ATYPE=1,1

　　DPOS=0,0

　　SPEED=1,1                 ''型材運行速度1m/s,60m/min

　　ACCEL=2,2

　　DECEL=2,2

　　SRAMP=200,200         '設置S曲線時間

　　OP(0,OFF)

　　MOVELINK(0,1,0,0,1,8) AXIS(0)     '型材運動1m前，工作臺靜止

　　MOVELINK(0.4,0.8,0.8,0,1,8) AXIS(0)     '工作臺加速階段

　　MOVELINK(0.2,0.2,0,0,1,8) AXIS(0)     '速度同步跟隨0.2m

　　MOVE_OP2(0,on,1000)         '刀具下剪，1s后回升(時間要計算好)

　　MOVELINK(0.4,0.8,0,0.8,1,8) AXIS(0)         '工作臺減速階段

　　MOVELINK(-1,1.2,0.5,0.5,1,8) AXIS(0)         '工作臺回到起始點

　　TRIGGER         '自動觸發(fā)示波器

　　VMOVE(1) AXIS(1)         '型材持續(xù)運動

　　參考軸和跟隨軸速度曲線平滑。

　　8    主MOVESLINK -- 自動凸輪2

　　此指令用于自定義的凸輪運動，該運動自動規(guī)劃中間曲線，不用計算凸輪表。

　　功能與MOVELINK相同，僅是參數(shù)設置區(qū)別，第3、4個參數(shù)，MOVELINK設置加減速過程的距離參數(shù)，MOVESLINK設置加減速過程的速度比例。

　　被連接軸為參考軸，連接軸為跟隨軸。

　　MOVESLINK (distance,link dist,start sp,end sp,link axis [,link options] [,ink pos] [,link offpos])

　　可選參數(shù)不填時，逗號不能省掉，控制器根據(jù)參數(shù)的位置來判斷是什么參數(shù)。

　　distance：從連接開始到結(jié)束，跟隨軸移動的距離，此參數(shù)可正可負，為正數(shù)正方向跟隨，為負數(shù)負方向跟隨，采用units單位。

　　link dist：參考軸在連接的整個過程中移動的絕對距離，采用units單位。

　　start sp：啟動時跟隨軸和參考軸的速度比例，units/units單位，負數(shù)表示跟隨軸負向運動。

　　end sp：結(jié)束時跟隨軸和參考軸的速度比例，units/units單位, 負數(shù)表示跟隨軸負向運動 注：當start sp = end sp = distance/link dist時，勻速運動。

　　link axis：參考軸的軸號。

　　link options：連接模式選項，不同的二進制位代表不同的意義。

　　link pos：當link options參數(shù)bit1置為1時，該參數(shù)表示參考軸在該絕對位置值時，連接開始。

　　link offpos：當link_options參數(shù)bit4置為1時，該參數(shù)表示主軸已經(jīng)運行完的相對位置。20170428以上固件支持。

　　在加速和減速階段為了與速度匹配，下一條MOVESLINK的start sp必須與當前MOVESLINK的end sp相同。

　　請確保指令傳遞的距離參數(shù)*UNITS是整數(shù)個脈沖，否則出現(xiàn)浮點數(shù)會導致運動有細微誤差。

　　例一：SRAMP=200,200

　　加工過程中，參考軸為型材，工作臺為跟隨軸，工作臺運動距離1，型材運動距離4。

　　RAPIDSTOP(2)

　　WAIT     IDLE(0)

　　WAIT     IDLE(1)

　　BASE(0,1)

　　UNITS=10000,10000

　　ATYPE=1,1

　　DPOS=0,0

　　SPEED=1,1     '型材運行速度1m/s,60m/min

　　ACCEL=2,2

　　DECEL=2,2

　　SRAMP=200,200

　　OP(0,OFF)

　　MOVESLINK(0,1,0,0,1) AXIS(0)             '型材運動1單位前，工作臺靜止

　　MOVESLINK(0.4,0.8,0,1,1) AXIS(0)       '工作臺加速階段，工作臺運動0.4，型材運動0.8，加速時，跟隨軸的速度為0，故跟隨軸和參考軸的速度比例為0，加速完成，跟隨軸和參考軸的速度相等，比例為1

　　MOVESLINK(0.2,0.2,1,1,1) AXIS(0)       '速度跟隨階段，速度一致，保持同步運動0.2

　　MOVESLINK(0.4,0.8,1,0,1) AXIS(0)       '工作臺減速階段，工作臺運動0.4，型材運動0.8，減速時，跟隨軸和參考軸的速度相等，比例為1，減速完成，跟隨軸的速度為0，故跟隨軸和參考軸的速度比例為0

　　MOVESLINK(-1,1.2,0,0,1) AXIS(0) '工作臺回到起始點，工作臺運動-1，型材運動1.2

　　TRIGGER                             '自動觸發(fā)示波器

　　VMOVE(1) AXIS(1)         '型材持續(xù)運動

　　對軸0和軸1的速度曲線設置平滑。

　　例二：SRAMP=0,0

　　RAPIDSTOP(2)

　　WAIT IDLE(0)

　　WAIT IDLE(1)

　　BASE(0,1)

　　UNITS=10000,10000

　　ATYPE=1,1

　　DPOS=0,0

　　SPEED=1,1         '型材運行速度1m/s,60m/min

　　ACCEL=2,2

　　DECEL=2,2

　　SRAMP=0,0

　　OP(0,OFF)

　　MOVESLINK(0,1,0,0,1)     AXIS(0)                  '型材運動1單位前，工作臺靜止

　　MOVESLINK(0.4,0.8,0,1,1)     AXIS(0)             '工作臺加速階段，工作臺運動0.4，型材運動0.8，加速時，跟隨軸的速度為0，故跟隨軸和參考軸的速度比例為0，加速完成，跟隨軸和參考軸的速度相等，比例為1

　　MOVESLINK(0.2,0.2,1,1,1)     AXIS(0)             '速度跟隨階段，速度一致，保持同步運動0.2

　　MOVESLINK(0.4,0.8,1,0,1)     AXIS(0)             '工作臺減速階段，工作臺運動0.4，型材運動0.8，減速時，跟隨軸和參考軸的速度相等，比例為1，減速完成，跟隨軸的速度為0，故跟隨軸和參考軸的速度比例為0

　　MOVESLINK(-1,1.2,0,0,1)     AXIS(0)              '工作臺回到起始點，工作臺運動-1，型材運動1.2

　　TRIGGER '自動觸發(fā)示波器

　　VMOVE(1) AXIS(1) '型材持續(xù)運動

　　S曲線只針對型材，工作臺速度不管設不設置曲線自動平滑。

　　正運動技術運動控制器多軸同步與電子凸輪指令的簡介就講到這里。更多學習視頻及圖文詳解請關注我們的公眾號“正運動小助手”。

　　本文由正運動技術原創(chuàng)，歡迎大家轉(zhuǎn)載，共同學習，一起提高中國智能制造水平。文章版權歸正運動技術所有，如有轉(zhuǎn)載請注明文章來源。